Halo的高级特性之ORACLE对象类型

Halo Tech 2025-03-27

在Oracle数据库中，对象类型（Object Type）是一种用户自定义的复合数据类型，支持面向对象编程（OOP）的特性。对象类型可以包含属性（数据字段）和方法（函数或过程），类似于其他编程语言中的类（Class）。对象类型可以存储在数据库中，并通过SQL或PL/SQL进行操作。Halo也支持Oracle对象类型的大部分功能。

Halo中对象类型的使用方法:

1. 创建对象类型

-- 创建对象类型
CREATE OR REPLACE TYPE person_type AS OBJECT (
    -- 对象属性
    name VARCHAR2(100),
    age NUMBER,


    -- 静态函数
    STATIC FUNCTION get_max_age RETURN NUMBER,


    -- 无参数的成员函数
    MEMBER FUNCTION get_info RETURN VARCHAR2,


    -- 有参数的成员函数
    MEMBER FUNCTION compare_age(p_other_age NUMBER) RETURN VARCHAR2
);
/
-- 创建对象类型的主体
CREATE OR REPLACE TYPE BODY person_type AS


    -- 静态函数实现
    STATIC FUNCTION get_max_age RETURN NUMBER IS
    BEGIN
        -- 这里简单返回一个固定值，实际应用中可以从表中查询等
        RETURN 120;
    END;


  -- 无参数的成员函数实现
    MEMBER FUNCTION get_info RETURN VARCHAR2 IS
    BEGIN
        RETURN 'Name: ' || self.name || ', Age: ' || TO_CHAR(self.age);
    END;


    -- 有参数的成员函数实现
    MEMBER FUNCTION compare_age(p_other_age NUMBER) RETURN VARCHAR2 IS
    BEGIN
        IF self.age > p_other_age THEN
            RETURN self.name || ' is older than the given age.';
        ELSIF self.age < p_other_age THEN
            RETURN self.name || ' is younger than the given age.';
        ELSE
            RETURN self.name || ' is of the same age as the given age.';
        END IF;
    END;
END;
/
复制

2. 对象类型的使用

(1) 构造函数

默认构造函数：参数顺序与类型规范中属性定义一致。

自定义构造函数：可在类型体中重载构造函数。

DECLARE                   
    v_person person_type; 
    v_info VARCHAR2(200);
BEGIN
    v_person := person_type('John Doe', 30); 
    v_info := v_person.get_info();
    DBMS_OUTPUT.PUT_LINE('Created person: ' || v_info);
END;
/
复制

(2) 静态函数

通过类型名直接调用，不依赖实例。

DECLARE
    v_max_age NUMBER;
BEGIN
    v_max_age := person_type.get_max_age();
    DBMS_OUTPUT.PUT_LINE('Max age: ' || v_max_age);
END;
/
复制

(3) 成员函数

通过对象实例调用，可以访问对象的属性

-- 无参数的成员函数
DECLARE
    v_person person_type;
    v_info VARCHAR2(200);
BEGIN
    v_person := person_type('Jane Smith', 25);
    v_info := v_person.get_info();
    DBMS_OUTPUT.PUT_LINE('Person info: ' || v_info);
END;
/


-- 有参数的成员函数
DECLARE
    v_person person_type;
    v_result VARCHAR2(200);
BEGIN
    v_person := person_type('Bob Johnson', 35);
    v_result := v_person.compare_age(30);
    DBMS_OUTPUT.PUT_LINE(v_result);
END;
/
复制